303 lines
10 KiB
Idris
303 lines
10 KiB
Idris
module Tests.Equal
|
||
|
||
import Quox.Equal as Lib
|
||
import Quox.Pretty
|
||
import Quox.Syntax.Qty.Three
|
||
import TAP
|
||
|
||
export
|
||
ToInfo (Error Three) where
|
||
toInfo (NotInScope x) =
|
||
[("type", "NotInScope"),
|
||
("name", show x)]
|
||
toInfo (ExpectedTYPE t) =
|
||
[("type", "ExpectedTYPE"),
|
||
("got", prettyStr True t)]
|
||
toInfo (ExpectedPi t) =
|
||
[("type", "ExpectedPi"),
|
||
("got", prettyStr True t)]
|
||
toInfo (ExpectedSig t) =
|
||
[("type", "ExpectedSig"),
|
||
("got", prettyStr True t)]
|
||
toInfo (ExpectedEq t) =
|
||
[("type", "ExpectedEq"),
|
||
("got", prettyStr True t)]
|
||
toInfo (BadUniverse k l) =
|
||
[("type", "BadUniverse"),
|
||
("low", show k),
|
||
("high", show l)]
|
||
toInfo (ClashT mode s t) =
|
||
[("type", "ClashT"),
|
||
("mode", show mode),
|
||
("left", prettyStr True s),
|
||
("right", prettyStr True t)]
|
||
toInfo (ClashU mode k l) =
|
||
[("type", "ClashU"),
|
||
("mode", show mode),
|
||
("left", prettyStr True k),
|
||
("right", prettyStr True l)]
|
||
toInfo (ClashQ pi rh) =
|
||
[("type", "ClashQ"),
|
||
("left", prettyStr True pi),
|
||
("right", prettyStr True rh)]
|
||
toInfo (ClashD p q) =
|
||
[("type", "ClashD"),
|
||
("left", prettyStr True p),
|
||
("right", prettyStr True q)]
|
||
|
||
|
||
0 M : Type -> Type
|
||
M = ReaderT (Definitions Three) (Either (Error Three))
|
||
|
||
parameters (label : String) (act : Lazy (M ()))
|
||
{default empty globals : Definitions Three}
|
||
testEq : Test
|
||
testEq = test label $ runReaderT globals act
|
||
|
||
testNeq : Test
|
||
testNeq = testThrows label (const True) $ runReaderT globals act
|
||
|
||
|
||
parameters {default 0 d, n : Nat}
|
||
{default new eqs : DimEq d}
|
||
subT : Term Three d n -> Term Three d n -> M ()
|
||
subT s t = Term.sub !ask eqs s t
|
||
|
||
equalT : Term Three d n -> Term Three d n -> M ()
|
||
equalT s t = Term.equal !ask eqs s t
|
||
|
||
subE : Elim Three d n -> Elim Three d n -> M ()
|
||
subE e f = Elim.sub !ask eqs e f
|
||
|
||
equalE : Elim Three d n -> Elim Three d n -> M ()
|
||
equalE e f = Elim.equal !ask eqs e f
|
||
|
||
|
||
export
|
||
tests : Test
|
||
tests = "equality & subtyping" :- [
|
||
note #""0=1 ⊢ 𝒥" means that 𝒥 holds in an inconsistent dim context"#,
|
||
|
||
"universes" :- [
|
||
testEq "★₀ ≡ ★₀" $
|
||
equalT (TYPE 0) (TYPE 0),
|
||
testNeq "★₀ ≢ ★₁" $
|
||
equalT (TYPE 0) (TYPE 1),
|
||
testNeq "★₁ ≢ ★₀" $
|
||
equalT (TYPE 1) (TYPE 0),
|
||
testEq "★₀ <: ★₀" $
|
||
subT (TYPE 0) (TYPE 0),
|
||
testEq "★₀ <: ★₁" $
|
||
subT (TYPE 0) (TYPE 1),
|
||
testNeq "★₁ ≮: ★₀" $
|
||
subT (TYPE 1) (TYPE 0)
|
||
],
|
||
|
||
"pi" :- [
|
||
note #""A ⊸ B" for (1 _ : A) → B"#,
|
||
note #""A ⇾ B" for (0 _ : A) → B"#,
|
||
testEq "A ⊸ B ≡ A ⊸ B" $
|
||
let tm = Arr One (FT "A") (FT "B") in
|
||
equalT tm tm,
|
||
testNeq "A ⇾ B ≢ A ⊸ B" $
|
||
let tm1 = Arr Zero (FT "A") (FT "B")
|
||
tm2 = Arr One (FT "A") (FT "B") in
|
||
equalT tm1 tm2,
|
||
testEq "0=1 ⊢ A ⇾ B ≢ A ⊸ B" $
|
||
let tm1 = Arr Zero (FT "A") (FT "B")
|
||
tm2 = Arr One (FT "A") (FT "B") in
|
||
equalT tm1 tm2 {eqs = ZeroIsOne},
|
||
testEq "A ⊸ B <: A ⊸ B" $
|
||
let tm = Arr One (FT "A") (FT "B") in
|
||
subT tm tm,
|
||
testNeq "A ⇾ B ≮: A ⊸ B" $
|
||
let tm1 = Arr Zero (FT "A") (FT "B")
|
||
tm2 = Arr One (FT "A") (FT "B") in
|
||
subT tm1 tm2,
|
||
testEq "★₀ ⇾ ★₀ ≡ ★₀ ⇾ ★₀" $
|
||
let tm = Arr Zero (TYPE 0) (TYPE 0) in
|
||
equalT tm tm,
|
||
testEq "★₀ ⇾ ★₀ <: ★₀ ⇾ ★₀" $
|
||
let tm = Arr Zero (TYPE 0) (TYPE 0) in
|
||
subT tm tm,
|
||
testNeq "★₁ ⊸ ★₀ ≢ ★₀ ⇾ ★₀" $
|
||
let tm1 = Arr Zero (TYPE 1) (TYPE 0)
|
||
tm2 = Arr Zero (TYPE 0) (TYPE 0) in
|
||
equalT tm1 tm2,
|
||
testEq "★₁ ⊸ ★₀ <: ★₀ ⊸ ★₀" $
|
||
let tm1 = Arr One (TYPE 1) (TYPE 0)
|
||
tm2 = Arr One (TYPE 0) (TYPE 0) in
|
||
subT tm1 tm2,
|
||
testNeq "★₀ ⊸ ★₀ ≢ ★₀ ⇾ ★₁" $
|
||
let tm1 = Arr Zero (TYPE 0) (TYPE 0)
|
||
tm2 = Arr Zero (TYPE 0) (TYPE 1) in
|
||
equalT tm1 tm2,
|
||
testEq "★₀ ⊸ ★₀ <: ★₀ ⊸ ★₁" $
|
||
let tm1 = Arr One (TYPE 0) (TYPE 0)
|
||
tm2 = Arr One (TYPE 0) (TYPE 1) in
|
||
subT tm1 tm2,
|
||
testEq "★₀ ⊸ ★₀ <: ★₀ ⊸ ★₁" $
|
||
let tm1 = Arr One (TYPE 0) (TYPE 0)
|
||
tm2 = Arr One (TYPE 0) (TYPE 1) in
|
||
subT tm1 tm2
|
||
],
|
||
|
||
"lambda" :- [
|
||
testEq "λ x ⇒ [x] ≡ λ x ⇒ [x]" $
|
||
equalT (Lam "x" $ TUsed $ BVT 0) (Lam "x" $ TUsed $ BVT 0),
|
||
testEq "λ x ⇒ [x] <: λ x ⇒ [x]" $
|
||
equalT (Lam "x" $ TUsed $ BVT 0) (Lam "x" $ TUsed $ BVT 0),
|
||
testEq "λ x ⇒ [x] ≡ λ y ⇒ [y]" $
|
||
equalT (Lam "x" $ TUsed $ BVT 0) (Lam "y" $ TUsed $ BVT 0),
|
||
testEq "λ x ⇒ [x] <: λ y ⇒ [y]" $
|
||
equalT (Lam "x" $ TUsed $ BVT 0) (Lam "y" $ TUsed $ BVT 0),
|
||
testNeq "λ x y ⇒ [x] ≢ λ x y ⇒ [y]" $
|
||
equalT (Lam "x" $ TUsed $ Lam "y" $ TUsed $ BVT 1)
|
||
(Lam "x" $ TUsed $ Lam "y" $ TUsed $ BVT 0),
|
||
testEq "λ x ⇒ [a] ≡ λ x ⇒ [a] (TUsed vs TUnused)" $
|
||
equalT (Lam "x" $ TUsed $ FT "a")
|
||
(Lam "x" $ TUnused $ FT "a"),
|
||
skipWith "(no η yet)" $
|
||
testEq "λ x ⇒ [f [x]] ≡ [f] (η)" $
|
||
equalT (Lam "x" $ TUsed $ E $ F "f" :@ BVT 0)
|
||
(FT "f")
|
||
],
|
||
|
||
"eq type" :- [
|
||
testEq "(★₀ = ★₀ : ★₁) ≡ (★₀ = ★₀ : ★₁)" $
|
||
let tm = Eq0 (TYPE 1) (TYPE 0) (TYPE 0) in
|
||
equalT tm tm,
|
||
testEq "A ≔ ★₁ ⊢ (★₀ = ★₀ : ★₁) ≡ (★₀ = ★₀ : A)"
|
||
{globals = fromList [("A", mkDef zero (TYPE 2) (TYPE 1))]} $
|
||
equalT (Eq0 (TYPE 1) (TYPE 0) (TYPE 0))
|
||
(Eq0 (FT "A") (TYPE 0) (TYPE 0))
|
||
],
|
||
|
||
todo "dim lambda",
|
||
|
||
"term closure" :- [
|
||
note "𝑖, 𝑗 for bound variables pointing outside of the current expr",
|
||
testEq "[𝑖]{} ≡ [𝑖]" $
|
||
equalT (CloT (BVT 0) id) (BVT 0) {n = 1},
|
||
testEq "[𝑖]{a/𝑖} ≡ [a]" $
|
||
equalT (CloT (BVT 0) (F "a" ::: id)) (FT "a"),
|
||
testEq "[𝑖]{a/𝑖,b/𝑗} ≡ [a]" $
|
||
equalT (CloT (BVT 0) (F "a" ::: F "b" ::: id)) (FT "a"),
|
||
testEq "(λy. [𝑖]){y/y, a/𝑖} ≡ λy. [a] (TUnused)" $
|
||
equalT (CloT (Lam "y" $ TUnused $ BVT 0) (F "a" ::: id))
|
||
(Lam "y" $ TUnused $ FT "a"),
|
||
testEq "(λy. [𝑖]){y/y, a/𝑖} ≡ λy. [a] (TUsed)" $
|
||
equalT (CloT (Lam "y" $ TUsed $ BVT 1) (F "a" ::: id))
|
||
(Lam "y" $ TUsed $ FT "a")
|
||
],
|
||
|
||
todo "term d-closure",
|
||
|
||
"free var" :-
|
||
let au_bu = fromList
|
||
[("A", mkDef Any (TYPE (U 1)) (TYPE (U 0))),
|
||
("B", mkDef Any (TYPE (U 1)) (TYPE (U 0)))]
|
||
au_ba = fromList
|
||
[("A", mkDef Any (TYPE (U 1)) (TYPE (U 0))),
|
||
("B", mkDef Any (TYPE (U 1)) (FT "A"))]
|
||
in [
|
||
testEq "A ≡ A" $
|
||
equalE (F "A") (F "A"),
|
||
testNeq "A ≢ B" $
|
||
equalE (F "A") (F "B"),
|
||
testEq "0=1 ⊢ A ≡ B" $
|
||
equalE {eqs = ZeroIsOne} (F "A") (F "B"),
|
||
testEq "A : ★₁ ≔ ★₀ ⊢ A ≡ (★₀ ∷ ★₁)" {globals = au_bu} $
|
||
equalE (F "A") (TYPE 0 :# TYPE 1),
|
||
testEq "A ≔ ★₀, B ≔ ★₀ ⊢ A ≡ B" {globals = au_bu} $
|
||
equalE (F "A") (F "B"),
|
||
testEq "A ≔ ★₀, B ≔ A ⊢ A ≡ B" {globals = au_ba} $
|
||
equalE (F "A") (F "B"),
|
||
testEq "A <: A" $
|
||
subE (F "A") (F "A"),
|
||
testNeq "A ≮: B" $
|
||
subE (F "A") (F "B"),
|
||
testEq "A : ★₃ ≔ ★₀, B : ★₃ ≔ ★₂ ⊢ A <: B"
|
||
{globals = fromList [("A", mkDef Any (TYPE 3) (TYPE 0)),
|
||
("B", mkDef Any (TYPE 3) (TYPE 2))]} $
|
||
subE (F "A") (F "B"),
|
||
testEq "A : ★₁👈 ≔ ★₀, B : ★₃ ≔ ★₂ ⊢ A <: B"
|
||
{globals = fromList [("A", mkDef Any (TYPE 1) (TYPE 0)),
|
||
("B", mkDef Any (TYPE 3) (TYPE 2))]} $
|
||
subE (F "A") (F "B"),
|
||
testEq "0=1 ⊢ A <: B" $
|
||
subE (F "A") (F "B") {eqs = ZeroIsOne}
|
||
],
|
||
|
||
"bound var" :- [
|
||
note "𝑖, 𝑗 for distinct bound variables",
|
||
testEq "𝑖 ≡ 𝑖" $
|
||
equalE (BV 0) (BV 0) {n = 1},
|
||
testNeq "𝑖 ≢ 𝑗" $
|
||
equalE (BV 0) (BV 1) {n = 2},
|
||
testEq "0=1 ⊢ 𝑖 ≡ 𝑗" $
|
||
equalE {n = 2, eqs = ZeroIsOne} (BV 0) (BV 1)
|
||
],
|
||
|
||
"application" :- [
|
||
testEq "f [a] ≡ f [a]" $
|
||
equalE (F "f" :@ FT "a") (F "f" :@ FT "a"),
|
||
testEq "f [a] <: f [a]" $
|
||
subE (F "f" :@ FT "a") (F "f" :@ FT "a"),
|
||
testEq "(λ x ⇒ [x] ∷ A ⊸ A) a ≡ ([a ∷ A] ∷ A) (β)" $
|
||
equalE
|
||
((Lam "x" (TUsed (BVT 0)) :# (Arr One (FT "A") (FT "A")))
|
||
:@ FT "a")
|
||
(E (FT "a" :# FT "A") :# FT "A"),
|
||
testEq "(λ x ⇒ [x] ∷ A ⊸ A) a ≡ a (βυ)" $
|
||
equalE
|
||
((Lam "x" (TUsed (BVT 0)) :# (Arr One (FT "A") (FT "A")))
|
||
:@ FT "a")
|
||
(F "a"),
|
||
testEq "(λ g ⇒ [g [x]] ∷ ⋯)) [f] ≡ (λ y ⇒ [f [y]] ∷ ⋯) [x] (β↘↙)" $
|
||
let a = FT "A"; a2a = (Arr One a a) in
|
||
equalE
|
||
((Lam "g" (TUsed (E (BV 0 :@ FT "x"))) :# Arr One a2a a) :@ FT "f")
|
||
((Lam "y" (TUsed (E (F "f" :@ BVT 0))) :# a2a) :@ FT "x"),
|
||
testEq "(λ x ⇒ [x] ∷ A ⊸ A) a <: a" $
|
||
subE
|
||
((Lam "x" (TUsed (BVT 0)) :# (Arr One (FT "A") (FT "A")))
|
||
:@ FT "a")
|
||
(F "a"),
|
||
testEq "f : A ⊸ A ≔ λ x ⇒ [x] ⊢ f [x] ≡ x"
|
||
{globals = fromList
|
||
[("f", mkDef Any (Arr One (FT "A") (FT "A"))
|
||
(Lam "x" (TUsed (BVT 0))))]} $
|
||
equalE (F "f" :@ FT "x") (F "x")
|
||
],
|
||
|
||
"dim application" :-
|
||
let refl : Term q d n -> Term q d n -> Elim q d n
|
||
refl a x = (DLam "_" $ DUnused x) :# (Eq0 a x x)
|
||
in
|
||
[
|
||
note #""refl [A] x" is an abbreviation for "(λᴰi ⇒ x) ∷ (x ≡ x : A)""#,
|
||
testEq "refl [A] x ≡ refl [A] x" $
|
||
equalE (refl (FT "A") (FT "x")) (refl (FT "A") (FT "x")),
|
||
testEq "p : (a ≡ b : A), q : (a ≡ b : A) ⊢ p ≡ q"
|
||
{globals =
|
||
let def = mkAbstract Zero $ Eq0 (FT "A") (FT "a") (FT "b") in
|
||
fromList [("p", def), ("q", def)]} $
|
||
equalE (F "p") (F "q")
|
||
],
|
||
|
||
todo "annotation",
|
||
|
||
todo "elim closure",
|
||
|
||
todo "elim d-closure",
|
||
|
||
"clashes" :- [
|
||
testNeq "★₀ ≢ ★₀ ⇾ ★₀" $
|
||
equalT (TYPE 0) (Arr Zero (TYPE 0) (TYPE 0)),
|
||
testEq "0=1 ⊢ ★₀ ≡ ★₀ ⇾ ★₀" $
|
||
equalT (TYPE 0) (Arr Zero (TYPE 0) (TYPE 0)) {eqs = ZeroIsOne},
|
||
todo "others"
|
||
]
|
||
]
|