quox/flake.nix

{ description = "quox: quantitative extensional type theory";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    idris2-pkgs.url = "github:claymager/idris2-pkgs";
    nixpkgs.follows = "idris2-pkgs/nixpkgs";
  };

  outputs = { self, nixpkgs, idris2-pkgs, flake-utils }:
    let systems = with flake-utils.lib.system;
          # [ x86_64-darwin x86_64-linux i686-linux ];    # FIXME
          [ x86_64-linux ];
    in
    flake-utils.lib.eachSystem systems (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ idris2-pkgs.overlay ];
        };
        builders = pkgs.idris2-pkgs._builders;

        packages = rec {
          quox-lib   = builders.idrisPackage ./lib   { };
          quox       = builders.idrisPackage ./exe   { extraPkgs = packages; };
          quox-tests = builders.idrisPackage ./tests { extraPkgs = packages; };
        };

        devShells =
          let mkDevShell = _: pkg:
                pkgs.mkShell { buildInputs = [ (builders.devEnv pkg) ]; };
              shells = packages //
                (with packages; { lib = quox-lib; test = quox-tests; });
          in builtins.mapAttrs mkDevShell shells;
      in {
        inherit packages devShells;
        defaultPackage = packages.quox;
        devShell = devShells.lib;
      }
    );
}